Is there a way to make a slideshow of all the videos and images contained in a single folder?

Solution 1:

1. Open /Applications/Photos.app and go to File>New Album.
2. Create a new Album with the name "Store Display"
3. Open /Applications/Utilities/Script Editor.app
4. Copy and Paste Script below
5. Go to File>Export
   • File Format: Application
6. Open Application
7. Select your folder that contains Photos and Videos
8. Click Choose
9. Celebrate!

Heres the code (edited by @wch1zpink) :

set imageNameExtensions to {"jpg", "jpeg", "png", "tiff", "bmp", "gif"}
set videoNameExtensions to {"mov", "mp4", "m4v", "avi"}
set nameExtensions to (videoNameExtensions & imageNameExtensions)

set myFolder to (choose folder) as text

set theChoice to display dialog ¬
    "Select Your Option" buttons {"Cancel", "Main Folder", "Main Folder And Sub-Folders"} ¬
    default button 3 ¬
    cancel button 1 ¬
    with title ¬
    "CHOOSE A FOLDER" giving up after 30

if button returned of theChoice is "Main Folder And Sub-Folders" then
    tell application "Finder"
        set mediaItems to (files of (entire contents of folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
else if button returned of theChoice is "Main Folder" then
    tell application "Finder"
        set mediaItems to (files of (folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
end if

tell application "Photos"
    import mediaItems into container named "Store Display" with skip check duplicates
    start slideshow using media items of album "Store Display"
end tell