How do I kill the Windows 10 Upgrade window?

Solution 1:

I have decided to convert my comment into an answer in case the link goes dead and for better visibility.

If You want to kill the Windows 10 upgrade window, You need to do these steppes one by one until it stops pestering You:

• Click customize in the system tray and turn off the Get Windows 10 app notification.

• Go to windows updates and uninstall KB3035583

• Open up regedit.exe using the Start search or by hitting WIN + R and pasting it into the field. Then browse down to the following key, creating it if it doesn’t exist: HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Gwx

  Once you are there, create a new 32-bit DWORD value on the right-hand side named DisableGwx, and give it a value of 1

step by step guide and source:
http://www.howtogeek.com/218856/how-do-you-disable-the-get-windows-10-icon-shown-in-the-notification-tray/

Solution 2:

The current year is 2018 and I continue to deal with this problem – because I’m greedy and I want to eat the cake and to keep it. Namely, I want to continue to use Windows 8.1 and keep the Windows 10 upgrade offer available – without the nagging window permanently cluttering my desktop.

I have solved it with an AutoHotkey script. It captures the unwanted window (either when it pops up or instantly, if it’s present already) and automatically minimizes it to tray. You can double click it later at any time to show the window again or to hide it again. (You can modify this solution to work for any window, not only Windows upgrade.) Here’s how it looks:

Install AutoHotkey, save the following script to your start-up folder – and you can forget about the Windows upgrade for as long as you want without cancelling it. This way you can eat your cake and keep it. You only need to edit appWinTitle and appWinText to reflect your Windows language.

; win10killer.ahk
; Minimise Windows 10 upgrade notice to tray.
;
; Based on:
; https://autohotkey.com/board/topic/124024-minimize-to-tray/
; https://www.reddit.com/r/AutoHotkey/comments/33djss/help_minimize_to_tray/
; 2018-02-01

#Persistent
appPath = C:\Windows\System32\wuauclt.exe
appWinTitle = Windows Update ahk_exe wuauclt.exe ; Change this to your language.
appWinText = Start the upgrade now ; Change this to your language.
appName = Windows 10 upgrade notice ; Arbitrary description.
hwnd =
ModifyAutohotkeyTrayIconAndMenu()
CaptureWindowAndMinimizeToTray()
WinWaitClose ahk_id %hwnd% ; Intended to wait forever.
MsgBox,,, %appName% was closed. Quitting script., 1 ; Should never happen.
ExitApp ; Should never happen.

TrayClick:
    OnTrayClick()
    return

ModifyAutohotkeyTrayIconAndMenu() {
    global appPath, appName
    Menu Tray, Icon, %appPath% ; Borrow icon from the upgrade executable.
    Menu Tray, Add, Show/hide %appName%, TrayClick
    Menu Tray, Default, Show/hide %appName%
}

CaptureWindowAndMinimizeToTray() {
    global hwnd
    global appPath, appWinTitle, appWinText
    DetectHiddenWindows On
    WinWait,, %appWinText% ; or: WinWait, %appWinTitle%
    hwnd := WinExist()
    WinHide ahk_id %hwnd%
}

OnTrayClick() { ; Show/hide target window on double click
    global hwnd
    if DllCall("IsWindowVisible", "Ptr", hwnd)
        WinHide ahk_id %hwnd%
    else {
        WinShow ahk_id %hwnd%
        WinActivate ahk_id %hwnd%
    }
}

Keywords to help people find this page: “Windows Upgrade | Your upgrade is ready to install | Save your work and leave your PC plugged in and turned on. The upgrade might take a while, but we’ll let you know when it’s done. | Schedule it for later / Start the upgrade now.”