Remove OneDrive from File Explorer [duplicate]

gpedit.msc -> Local Computer Policy\Computer Configuration\Administrative Templates\Windows Components\OneDrive

Enable "Prevent the usage of OneDrive for file storage". This will disable and remove everything after a restart

The above answer doesn't work for Home users as they do not have gpedit.msc. I do understand you weren't looking for Registry fixes but this appear to be the only way. (You can stop OneDrive from booting but it doesn't remove it completely)

Take a look at this thread at Reddit

EDIT:
Pasted the Reddit post incase something changes

--

If you want to remove OneDrive permanently, do the following:

Create a text file by opening Notepad

Go on the following link and copy/paste the code into the text file:

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo Closing OneDrive process.
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo Uninstalling OneDrive.
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo Removing OneDrive leftovers.
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo Removeing OneDrive from the Explorer Side Panel.
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1

pause

Then save as RemoveOneDrive.bat and exit

Run the script with admin rights and One Drive will be gone