How do you show only complete albums in iTunes 11?

iTunes 11 seems to revolve around the screen that shows you all of the different albums that you own. However, the vast majority of the albums iTunes is showing me are albums from which I own only one song, and it is making it difficult to find those albums that are actually complete.

In iTunes 11, how do you filter the albums displayed in the Albums pane?

Make a smart playlist with the following filter - Comments contains Full Album. For each album I want to add, I click on Get Info and add Full Album to the comments field

You can't. Write a suggestion to Apple at: http://www.apple.com/feedback/itunesapp.html

You can create a playlist that contains all full albums in your library using AppleScript. The code below is just a small modification to the script linked in Kirk's answer so that it creates one playlist instead of one per album. It's slow (takes maybe 5 minutes to run through my library) and is very sensitive to any metadata inaccuracies, but it works for me.

-- Creates one playlist of all full albums you have in iTunes
-- Set the playlistPrefix and playlistSuffix as desired before running

-- Original script by duozmo on Ask Different
-- http://hints.macworld.com/article.php?story=20130201061128257
-- http://apple.stackexchange.com/a/77626

-- Based on code by Brad Campbell
-- http://www.bradcampbell.com/2009/05/26/make-a-whole-album-playlist-in-itunes/

tell application "iTunes"
    set albumPlaylistName to "Full Albums"
    -- Create playlist
    if user playlist albumPlaylistName exists then
        try
            delete tracks of user playlist albumPlaylistName
        end try
    else
        make new user playlist with properties {name:albumPlaylistName}
    end if

    set albumBuckets to {} as list
    set allSongs to (every track of library playlist 1 whose enabled is true and podcast is false and kind contains "audio") as list

    -- Find all partial albums in iTunes
    repeat with currentTrack in allSongs
        set albumName to album of currentTrack as text
        set artistName to artist of currentTrack as text

        -- First check for missing values, then perform integer comparison
        -- Zero is on the left to force interger type coercion, just in case
        if album of currentTrack is not missing value and 0 is less than length of albumName then
            if artist of currentTrack is not missing value and 0 is less than length of artistName then
                if track number of currentTrack is not missing value and 0 is less than track number of currentTrack then
                    if track count of currentTrack is not missing value and 0 is less than track count of currentTrack then
                        if albumBuckets does not contain album of currentTrack then
                            copy album of currentTrack to the end of albumBuckets
                        end if
                    end if
                end if
            end if
        end if

    end repeat

    repeat with currentAlbum in albumBuckets
        set albumSongs to (every track of library playlist 1 whose album is currentAlbum)
        set firstTrack to first item of albumSongs

        -- Filter album list to act only on full albums
        if (count of albumSongs) is equal to track count of first item of albumSongs and 1 is less than (count of albumSongs) then
            -- This is a full album, construct the playlist

            -- Sort tracks by track number
            set albumSongsSorted to {} as list
            repeat with i from 1 to (count of albumSongs)
                repeat with trk in albumSongs
                    if track number of trk is i then
                        set nextSong to trk
                        copy nextSong to the end of albumSongsSorted
                    end if
                end repeat
            end repeat

            try
                repeat with trk in albumSongsSorted
                    duplicate trk to user playlist albumPlaylistName
                end repeat
            end try
        end if
    end repeat

    display dialog albumPlaylistName & " playlist created!"
end tell

Another option would be to use Doug's Random Full Albums script if you just want iTunes to act like a CD changer on album shuffle mode.