How to take screenshots in rapid succession

Spamming cmd-shift-3 only takes a screenshot every second or so.

How can I take screenshots more frequently than this? So that e.g. double-tapping cmd-shift-3 will take two screenshots?

I remember being able to take fast screenshots in the past, maybe before Big Sur or Catalina.

⇧⌘3 works as fast as I can press in Big Sur 11.4 Beta 1 and I don't remember having this issue on previous versions of Big Sur.

Try with a new user account to rule out interference from a running app.

I figure you may find this useful.

This following AppleScript code will take multiple screenshots with a delay of .01 seconds between each.

Hopefully you have basic knowledge of how to use AppleScript

global captureCount, theCount
property theCounter : {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 20, 30, 50, 100}
property someName : "Screen Shot " -- Edit This To Desired Saved File Name
property delayInSeconds : 0.01 -- Edit To Desired Delay In Seconds For Screencaptures

activate
set captureCount to (choose from list theCounter ¬
    with title "Auto Screen Capture" with prompt ¬
    "Choose How Many Screenshots To Take" default items 5 ¬
    OK button name "OK" cancel button name "Cancel") as text as number

activate
set saveToFolder to (choose folder with prompt "Select A \"Save To\" Folder") as text

set theCount to 1

tell application "Finder"
    if alias (saveToFolder & someName & theCount & ".png") exists then
        repeat while alias (saveToFolder & someName & theCount & ".png") exists
            set theCount to theCount + 1
            delay 0.1
        end repeat
    end if
end tell

takeScreenShots(saveToFolder, someName, delayInSeconds)

on takeScreenShots(saveToFolder, someName, delayInSeconds)
    repeat captureCount times
        do shell script "screencapture -x " & quoted form of POSIX path ¬
            of (saveToFolder & someName & theCount & ".png")
        delay delayInSeconds
        set theCount to theCount + 1
    end repeat
end takeScreenShots

tell application "Finder"
    activate
    select alias saveToFolder
end tell