Is it possible to export from the Photos app without the dual dialogs?

In the macOS Photos app, select one or more photos and then choose > File > Export > Export 1 Photo. A popup dialog appears with options for the exported image:

Accept the defaults then choose Export, at which time a second dialog appears asking where the images should be stored. This also applies if you use the keyboard shortcut shift-command-E.

This is a bit of a pain when exporting lots of images in a session, especially since I always take the default options on both dialogs.

Are there any options or tricks for avoiding these dialogs, or at least removing the first dialog (perhaps via a default export setting)?

As an example, in Adobe Lightroom there is the ability to create an Export Preset, which doesn't require any confirmation or interaction. Lightroom can also Export With Previous which also doesn't require further confirmation after the first time it's used. Is anything like this available in macOS Photos?

As I mentioned in a comment, anytime I have something repetitive to do, I script it in one form or another, and this is how I handle your scenario.

In Automator, create a new Service workflow with the following settings:

• Service receives no input in Photos

Add a Run AppleScript action.

• Replace the default code with the following example AppleScript code:

  set thisLocation to (path to desktop)
  
  tell application "Photos"
      set theseItems to selection
      if theseItems is not {} then
          -- # Remove the '--' from in front of 'with' to export the original files.
          export theseItems to thisLocation -- with using originals 
      else
          display dialog "No files were selected to export!" buttons {"OK"} ¬
              default button 1 with title "Nothing To Do" with icon 1
      end if
  end tell
  

Save the Automator Service workflow, e.g.: Export Selected Files

Assign a keyboard shortcut for it, in:

System Preferences > Keyboard > Shortcuts > Services > General

• Example: Export Selected Files       ⌃⌘E

Now in Photos, after having selected the file(s) to export, press ⌃⌘E and the selection is exported to the Desktop. No need to deal with multiple dialog boxes as when pressing ⇧⌘E.

Obviously this is just example AppleScript code and while thisLocation is set to the Desktop, nonetheless it can be set wherever you'd like, where the folder already exists. It just has to be in the form of an alias if not using any of the folder constant path to (folder) locations e.g.:

set thisLocation to alias "Macintosh HD:Temp:"

Also, on a side note, Automator offers a number of different actions for Photos and those along with other actions provided can make for nice solutions to some repetitive tasks.

Note: As stated, this is just example AppleScript code and can be modified as needed beyond modifying the value of thisLocation, as wanted, e.g. adding with using originals at the end of export theseItems to thisLocation, or other code as wanted. The onus is upon the User to add any error handling that may be appropriate and or necessary.

When using a Run AppleScript action in Automator, you may find it handy to test your AppleScript code in Script Editor, where you'll have access to the AppleScript Dictionary for Photos, in the Library available from the Window menu, or press ⇧⌘L in Script Editor.

Perhaps not the best answer, but in case there are no better alternatives...

I just drag them to the desktop [or open folder] which saves the current edited version, no dialog required.
Multi-selections work, as well as single items.