How can I prevent Windows Explorer from suggesting hidden folders?

Solution 1:

The drop down isn't showing you hidden folders, it's showing you most recently visited places that you either typed into the address bar, or navigated to using the paths/arrows in the address bar itself; that's why the "Don't Show Hidden Folder" option doesn't affect it. :)

You can manually delete the list by right-clicking the address bar and clicking "Delete History".

You can also use RegEdit to access the HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\TypedPaths registry key and remove the entries from inside.

Perhaps Export a blank copy of that registry key and import it via a log-out script (using reg.exe in a batch file, or alike) to ensure it's been cleaned at logout.

Solution 2:

Apparently Windows does not provide an option to prevent it.

Instead, you can manullay run a batch script whenever you want to delete those history entries. This may help:

@echo OFF

SetLocal EnableExtensions EnableDelayedExpansion

set key=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\TypedPaths

for /f "delims=" %%A in ('reg query %key%') do (
    for /f "tokens=1,2,3 delims= " %%B in ("%%A") do (
        set name=%%B
        set type=%%C
        set data=%%D

        if exist !data! (
            set attribs=%%~aD
            echo !name! !type! !data! !attribs!
            set hidden=!attribs:~3,1!
            if !hidden!==- (
                echo !name! is not hidden.
            ) else (
                reg delete %key% /v !name! /f > nul
                echo !name! was removed.
            )
            echo.
        )
    )
)

pause

I think the option is not provided because it is not that simple to decide what to do in many cases like:

• Hidden attribute may be set/reset after url is visited.
• Resource pointed by url may be non-local.
• Visited file may be deleted.