Webpage works in IE, Chrome and Firefox, but not when using the .NET WebBrowser control
I'm using the WebBrowser control in Visual Studio 2010 and trying to display the page: http://lk21.org.
Inside that webpage there are lots of scripts loaded, and it works fine if I open it through a web browser such as Firefox, Chrome, and the latest version of IE.
My question is, why does it display "Bad Request" when I tried using the WebBrowser component to navigate to that page?
Check this out:
UPDATE:
The page loads nicely using Visual Vincent's answer.
However the flash videos on the website (or I think it's something similar to flash) is unable to be played. See the comparison in the images below.
The strange thing is, if I open YouTube the flash works well. After a bit research, it seems to be caused by something else. Any clue how to solve it?
Internet Explorer - works fine:
WebBrowser control - for some reason the video is stuck and can't be played:
It has probably got to do with that the WebBrowser control by default uses a document emulation mode of IE 7, meaning all pages are handled using the Internet Explorer 7 engine. Since that version is quite old most websites today are not compatible with it, which affects the functionality when you visit the page.
You can change this behaviour by adding a value for your application in the registry key Software\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION in either the HKEY_LOCAL_MACHINE hive or HKEY_CURRENT_USER. By doing so you are forcing your application to use a specific version of the IE engine.
I've written a class which will help you with this:
'A class for changing the WebBrowser control's document emulation.
'Written by Visual Vincent, 2017.
Imports Microsoft.Win32
Imports System.Security
Imports System.Windows.Forms
Public NotInheritable Class InternetExplorer
Private Sub New()
End Sub
Public Const InternetExplorerRootKey As String = "Software\Microsoft\Internet Explorer"
Public Const BrowserEmulationKey As String = InternetExplorerRootKey & "\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION"
Public Const ActiveXObjectCachingKey As String = InternetExplorerRootKey & "\MAIN\FeatureControl\FEATURE_OBJECT_CACHING"
Private Shared ReadOnly WebBrowserInstance As New WebBrowser 'Used to get the current IE version in a .NET-friendly manner.
Public Enum BrowserEmulation As Integer
IE7 = 7000
IE8 = 8000
IE8Standards = 8888
IE9 = 9000
IE9Standards = 9999
IE10 = 10000
IE10Standards = 10001
IE11 = 11000
IE11Edge = 11001
End Enum
Public Shared Sub SetLatestBrowserEmulation(ByVal Root As RegistryRoot)
Dim Emulation As BrowserEmulation = BrowserEmulation.IE7
Select Case WebBrowserInstance.Version.Major
Case Is >= 11 : Emulation = BrowserEmulation.IE11Edge
Case 10 : Emulation = BrowserEmulation.IE10Standards
Case 9 : Emulation = BrowserEmulation.IE9Standards
Case 8 : Emulation = BrowserEmulation.IE8Standards
End Select
InternetExplorer.SetBrowserEmulation(Root, Emulation)
End Sub
Public Shared Sub SetBrowserEmulation(ByVal Root As RegistryRoot, ByVal Emulation As BrowserEmulation)
Using RootKey As RegistryKey = Root.Root
Dim EmulationKey As RegistryKey = RootKey.OpenSubKey(BrowserEmulationKey, True)
If EmulationKey Is Nothing Then EmulationKey = RootKey.CreateSubKey(BrowserEmulationKey, RegistryKeyPermissionCheck.ReadWriteSubTree)
Using EmulationKey
EmulationKey.SetValue(Process.GetCurrentProcess().ProcessName & ".exe", CType(Emulation, Integer), RegistryValueKind.DWord)
End Using
End Using
End Sub
Public Shared Sub SetActiveXObjectCaching(ByVal Root As RegistryRoot, ByVal Enabled As Boolean)
Using RootKey As RegistryKey = Root.Root
Dim ObjectCachingKey As RegistryKey = RootKey.OpenSubKey(ActiveXObjectCachingKey, True)
If ObjectCachingKey Is Nothing Then ObjectCachingKey = RootKey.CreateSubKey(ActiveXObjectCachingKey, RegistryKeyPermissionCheck.ReadWriteSubTree)
Using ObjectCachingKey
ObjectCachingKey.SetValue(Process.GetCurrentProcess().ProcessName & ".exe", CType(If(Enabled, 1, 0), Integer), RegistryValueKind.DWord)
End Using
End Using
End Sub
Public NotInheritable Class RegistryRoot
Private _root As RegistryKey
Public ReadOnly Property Root As RegistryKey
Get
Return _root
End Get
End Property
Public Shared ReadOnly Property HKEY_LOCAL_MACHINE As RegistryRoot
Get
Return New RegistryRoot(Registry.LocalMachine)
End Get
End Property
Public Shared ReadOnly Property HKEY_CURRENT_USER As RegistryRoot
Get
Return New RegistryRoot(Registry.CurrentUser)
End Get
End Property
Private Sub New(ByVal Root As RegistryKey)
Me._root = Root
End Sub
End Class
End Class
To use it, put one of these lines in the application's Startup event:
InternetExplorer.SetLatestBrowserEmulation(InternetExplorer.RegistryRoot.HKEY_LOCAL_MACHINE)
'HKEY_CURRENT_USER is recommended if you do not want to run your application with administrative privileges.
InternetExplorer.SetLatestBrowserEmulation(InternetExplorer.RegistryRoot.HKEY_CURRENT_USER)
(NOTE: Using the HKEY_LOCAL_MACHINE root requires administrative privileges)
The InternetExplorer.SetLatestBrowserEmulation() method will set the browser emulation for your application, in the specified registry root, to the latest INSTALLED version of Internet Explorer.
However using the InternetExplorer.SetBrowserEmulation() method you can manually control what IE version it should use (not recommended!).
Read more:
Internet Feature Controls - Browser emulation
Application.StartupeventHow to: Handle Application Events (Visual Basic)
EDIT
I seem to be unable to enter that site at all, but from what I've read there have been problems with Flash hosted in the WebBrowser control.
What you can try is to disable the ActiveX Object Caching feature, which can apparently cause some issues for Flash controls.
I updated the above InternetExplorer class. Copy-paste it, then add this line to your application's startup event:
InternetExplorer.SetActiveXObjectCaching(InternetExplorer.RegistryRoot.HKEY_CURRENT_USER, False)
If it still doesn't work then I'm afraid you're out of luck. I have not been able to find anything else that is useful.
Based on @Visual Vincent answer, here I did a reworked solution:
1 - IEBrowserEmulationMode enumeration:
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Specifies a Internet Explorer browser emulation mode.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <remarks>
''' <see href="https://docs.microsoft.com/en-us/previous-versions/windows/internet-explorer/ie-developer/general-info/ee330730(v=vs.85)"/>
''' </remarks>
''' ----------------------------------------------------------------------------------------------------
Public Enum IEBrowserEmulationMode As Integer
''' <summary>
''' Webpages containing standards-based !DOCTYPE directives are displayed in IE7 Standards mode.
''' </summary>
IE7 = 7000
''' <summary>
''' Webpages containing standards-based !DOCTYPE directives are displayed in IE8 mode.
''' </summary>
IE8 = 8000
''' <summary>
''' Webpages are displayed in IE8 Standards mode, regardless of the declared !DOCTYPE directive.
''' <para></para>
''' Failing to declare a !DOCTYPE directive causes the page to load in Quirks.
''' </summary>
IE8Standards = 8888
''' <summary>
''' Webpages containing standards-based !DOCTYPE directives are displayed in IE9 mode.
''' </summary>
IE9 = 9000
''' <summary>
''' Webpages are displayed in IE9 Standards mode, regardless of the declared !DOCTYPE directive.
''' <para></para>
''' Failing to declare a !DOCTYPE directive causes the page to load in Quirks.
''' </summary>
IE9Standards = 9999
''' <summary>
''' Webpages containing standards-based !DOCTYPE directives are displayed in IE10 Standards mode.
''' </summary>
IE10 = 10000
''' <summary>
''' Webpages are displayed in IE10 Standards mode, regardless of the !DOCTYPE directive.
''' </summary>
IE10Standards = 10001
''' <summary>
''' Webpages containing standards-based !DOCTYPE directives are displayed in IE11 edge mode.
''' </summary>
IE11 = 11000
''' <summary>
''' Webpages are displayed in IE11 edge mode, regardless of the declared !DOCTYPE directive.
''' <para></para>
''' Failing to declare a !DOCTYPE directive causes the page to load in Quirks.
''' </summary>
IE11Edge = 11001
End Enum
2 - RegistryScope enumeration.
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Specifies a registry scope (a root key).
''' </summary>
''' ----------------------------------------------------------------------------------------------------
Public Enum RegistryScope As Integer
''' <summary>
''' This refers to the HKEY_LOCAL_MACHINE (or HKLM) registry root key.
''' <para></para>
''' Configuration changes made on the subkeys of this root key will affect all users.
''' </summary>
Machine = 0
''' <summary>
''' This refers to the HKEY_CURRENT_USER (or HKCU) registry root key.
''' <para></para>
''' Configuration changes made on the subkeys of this root key will affect only the current user.
''' </summary>
CurrentUser = 1
End Enum
3 - BrowserEmulationMode property, to get or set the IE Browser Emulation mode for the current application.
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Gets or sets the Internet Explorer browser emulation mode for the current application.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <seealso href="https://docs.microsoft.com/en-us/previous-versions/windows/internet-explorer/ie-developer/general-info/ee330730(v=vs.85)"/>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example to get, set and verify the IE browser emulation mode for the current process.
''' <code>
''' Dim scope As RegistryScope = RegistryScope.CurrentUser
''' Dim oldMode As IEBrowserEmulationMode
''' Dim newMode As IEBrowserEmulationMode
'''
''' oldMode = BrowserEmulationMode(scope)
''' BrowserEmulationMode(scope) = IEBrowserEmulationMode.IE11Edge
''' newMode = BrowserEmulationMode(scope)
'''
''' Console.WriteLine(String.Format("Old Mode: {0} ({1})", oldMode, CStr(oldMode)))
''' Console.WriteLine(String.Format("New Mode: {0} ({1})", newMode, CStr(newMode)))
'''
''' Dim f As New Form() With {.Size = New Size(1280, 720)}
''' Dim wb As New WebBrowser With {.Dock = DockStyle.Fill}
''' f.Controls.Add(wb)
''' f.Show()
''' wb.Navigate("http://www.whatversion.net/browser/")
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="scope">
''' The registry scope.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <value>
''' The Internet Explorer browser emulation mode.
''' </value>
''' ----------------------------------------------------------------------------------------------------
Public Shared Property BrowserEmulationMode(ByVal scope As RegistryScope) As IEBrowserEmulationMode
<DebuggerStepThrough>
Get
Return GetIEBrowserEmulationMode(Process.GetCurrentProcess().ProcessName, scope)
End Get
<DebuggerStepThrough>
Set(value As IEBrowserEmulationMode)
SetIEBrowserEmulationMode(Process.GetCurrentProcess().ProcessName, scope, value)
End Set
End Property
3 - GetIEBrowserEmulationMode function and SetIEBrowserEmulationMode method, to get or set the IE Browser Emulation mode for a external application.
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Gets the Internet Explorer browser emulation mode for the specified process.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <seealso href="https://docs.microsoft.com/en-us/previous-versions/windows/internet-explorer/ie-developer/general-info/ee330730(v=vs.85)"/>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code>
''' Dim processName As String = Process.GetCurrentProcess().ProcessName
''' Dim scope As RegistryScope = RegistryScope.CurrentUser
''' Dim mode As IEBrowserEmulationMode = GetIEBrowserEmulationMode(processName, scope)
'''
''' Console.WriteLine(String.Format("Mode: {0} ({1})", mode, CStr(mode)))
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="processName">
''' The process name (eg. 'cmd.exe').
''' </param>
'''
''' <param name="scope">
''' The registry scope.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' The resulting <see cref="IEBrowserEmulationMode"/>.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
''' <exception cref="NotSupportedException">
''' </exception>
''' ----------------------------------------------------------------------------------------------------
<DebuggerStepThrough>
Public Shared Function GetIEBrowserEmulationMode(ByVal processName As String, ByVal scope As RegistryScope) As IEBrowserEmulationMode
processName = Path.GetFileNameWithoutExtension(processName)
Using rootKey As RegistryKey = If(scope = RegistryScope.CurrentUser,
RegistryKey.OpenBaseKey(RegistryHive.CurrentUser, RegistryView.Default),
RegistryKey.OpenBaseKey(RegistryHive.LocalMachine, RegistryView.Default)),
subKey As RegistryKey = rootKey.CreateSubKey("Software\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION",
RegistryKeyPermissionCheck.ReadSubTree)
Dim value As Integer =
CInt(subKey.GetValue(String.Format("{0}.exe", processName), 0, RegistryValueOptions.None))
' If no browser emulation mode is retrieved from registry, then return default version for WebBrowser control.
If (value = 0) Then
Return IEBrowserEmulationMode.IE7
End If
If [Enum].IsDefined(GetType(IEBrowserEmulationMode), value) Then
Return DirectCast(value, IEBrowserEmulationMode)
Else
Throw New NotSupportedException(String.Format("Undefined browser emulation value retrieved from registry: '{0}'", value))
End If
End Using
End Function
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Gets the Internet Explorer browser emulation mode for the specified process.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <seealso href="https://docs.microsoft.com/en-us/previous-versions/windows/internet-explorer/ie-developer/general-info/ee330730(v=vs.85)"/>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code>
''' Dim p As Process = Process.GetCurrentProcess()
''' Dim scope As RegistryScope = RegistryScope.CurrentUser
''' Dim mode As IEBrowserEmulationMode = GetIEBrowserEmulationMode(p, scope)
'''
''' Console.WriteLine(String.Format("Mode: {0} ({1})", mode, CStr(mode)))
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="p">
''' The process.
''' </param>
'''
''' <param name="scope">
''' The registry scope.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' The resulting <see cref="IEBrowserEmulationMode"/>.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
''' <exception cref="NotSupportedException">
''' </exception>
''' ----------------------------------------------------------------------------------------------------
<DebuggerStepThrough>
Public Shared Function GetIEBrowserEmulationMode(ByVal p As Process, ByVal scope As RegistryScope) As IEBrowserEmulationMode
Return GetIEBrowserEmulationMode(p.ProcessName, scope)
End Function
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Sets the Internet Explorer browser emulation mode for the specified process.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <seealso href="https://docs.microsoft.com/en-us/previous-versions/windows/internet-explorer/ie-developer/general-info/ee330730(v=vs.85)"/>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code>
''' Dim processName As String = Process.GetCurrentProcess().ProcessName
''' Dim scope As RegistryScope = RegistryScope.CurrentUser
''' Dim oldMode As IEBrowserEmulationMode
''' Dim newMode As IEBrowserEmulationMode
'''
''' oldMode = GetIEBrowserEmulationMode(processName, scope)
''' SetIEBrowserEmulationMode(processName, scope, IEBrowserEmulationMode.IE11Edge)
''' newMode = GetIEBrowserEmulationMode(processName, scope)
'''
''' Console.WriteLine(String.Format("Old Mode: {0} ({1})", oldMode, CStr(oldMode)))
''' Console.WriteLine(String.Format("New Mode: {0} ({1})", newMode, CStr(newMode)))
'''
''' Dim f As New Form() With {.Size = New Size(1280, 720)}
''' Dim wb As New WebBrowser With {.Dock = DockStyle.Fill}
''' f.Controls.Add(wb)
''' f.Show()
''' wb.Navigate("http://www.whatversion.net/browser/")
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="processName">
''' The process name (eg. 'cmd.exe').
''' </param>
'''
''' <param name="scope">
''' The registry scope.
''' </param>
'''
''' <param name="mode">
''' The Internet Explorer browser emulation mode to set.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <exception cref="NotSupportedException">
''' </exception>
''' ----------------------------------------------------------------------------------------------------
<DebuggerStepThrough>
Public Shared Sub SetIEBrowserEmulationMode(ByVal processName As String, ByVal scope As RegistryScope, ByVal mode As IEBrowserEmulationMode)
processName = Path.GetFileNameWithoutExtension(processName)
Dim currentIEBrowserEmulationMode As IEBrowserEmulationMode = GetIEBrowserEmulationMode(processName, scope)
If (currentIEBrowserEmulationMode = mode) Then
Exit Sub
End If
Using rootKey As RegistryKey = If(scope = RegistryScope.CurrentUser,
RegistryKey.OpenBaseKey(RegistryHive.CurrentUser, RegistryView.Default),
RegistryKey.OpenBaseKey(RegistryHive.LocalMachine, RegistryView.Default)),
subKey As RegistryKey = rootKey.CreateSubKey(
"Software\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION",
RegistryKeyPermissionCheck.ReadWriteSubTree)
subKey.SetValue(String.Format("{0}.exe", processName),
DirectCast(mode, Integer), RegistryValueKind.DWord)
End Using
End Sub
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Sets the Internet Explorer browser emulation mode for the specified process.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <seealso href="https://docs.microsoft.com/en-us/previous-versions/windows/internet-explorer/ie-developer/general-info/ee330730(v=vs.85)"/>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code>
''' Dim processName As Process = Process.GetCurrentProcess()
''' Dim scope As RegistryScope = RegistryScope.CurrentUser
''' Dim oldMode As IEBrowserEmulationMode
''' Dim newMode As IEBrowserEmulationMode
'''
''' oldMode = GetIEBrowserEmulationMode(p, scope)
''' SetIEBrowserEmulationMode(p, scope, IEBrowserEmulationMode.IE11Edge)
''' newMode = GetIEBrowserEmulationMode(p, scope)
'''
''' Console.WriteLine(String.Format("Old Mode: {0} ({1})", oldMode, CStr(oldMode)))
''' Console.WriteLine(String.Format("New Mode: {0} ({1})", newMode, CStr(newMode)))
'''
''' Dim f As New Form() With {.Size = New Size(1280, 720)}
''' Dim wb As New WebBrowser With {.Dock = DockStyle.Fill}
''' f.Controls.Add(wb)
''' f.Show()
''' wb.Navigate("http://www.whatversion.net/browser/")
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="p">
''' The process.
''' </param>
'''
''' <param name="scope">
''' The registry scope.
''' </param>
'''
''' <param name="mode">
''' The Internet Explorer browser emulation mode to set.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <exception cref="NotSupportedException">
''' </exception>
''' ----------------------------------------------------------------------------------------------------
<DebuggerStepThrough>
Public Shared Sub SetIEBrowserEmulationMode(ByVal p As Process, ByVal scope As RegistryScope, ByVal mode As IEBrowserEmulationMode)
SetIEBrowserEmulationMode(p.ProcessName, scope, mode)
End Sub
Usage example to get, set and verify the IE browser emulation mode for the current process:
Dim scope As RegistryScope = RegistryScope.CurrentUser
Dim oldMode As IEBrowserEmulationMode
Dim newMode As IEBrowserEmulationMode
oldMode = BrowserEmulationMode(scope)
BrowserEmulationMode(scope) = IEBrowserEmulationMode.IE11Edge
newMode = BrowserEmulationMode(scope)
Console.WriteLine(String.Format("Old Mode: {0} ({1})", oldMode, CStr(oldMode)))
Console.WriteLine(String.Format("New Mode: {0} ({1})", newMode, CStr(newMode)))
Dim f As New Form() With {.Size = New Size(1280, 720)}
Dim wb As New WebBrowser With {.Dock = DockStyle.Fill}
f.Controls.Add(wb)
f.Show()
wb.Navigate("http://www.whatversion.net/browser/")
Usage example to get, set and verify the IE browser emulation mode for a specific process:
Dim processName As String = Process.GetCurrentProcess().ProcessName
Dim scope As RegistryScope = RegistryScope.CurrentUser
Dim oldMode As IEBrowserEmulationMode
Dim newMode As IEBrowserEmulationMode
oldMode = GetIEBrowserEmulationMode(processName, scope)
SetIEBrowserEmulationMode(processName, scope, IEBrowserEmulationMode.IE11Edge)
newMode = GetIEBrowserEmulationMode(processName, scope)
Console.WriteLine(String.Format("Old Mode: {0} ({1})", oldMode, CStr(oldMode)))
Console.WriteLine(String.Format("New Mode: {0} ({1})", newMode, CStr(newMode)))
Dim f As New Form() With {.Size = New Size(1280, 720)}
Dim wb As New WebBrowser With {.Dock = DockStyle.Fill}
f.Controls.Add(wb)
f.Show()
wb.Navigate("http://www.whatversion.net/browser/")