Simplify $\Gamma\left(\frac27\right) \Gamma\left(\frac{11}{42}\right)/\;\Gamma\left(\frac1{21}\right)$ to elementary terms

The product given by OP can indeed be expressed elementarily. I will give a procedural proof.

I will write $x\sim y$ if $x/y$ is a product of algebraic numbers and a rational power of $\pi$. The following are famous properties of gamma function: $$\tag{1}\Gamma(x) \Gamma(1-x) \sim 1 $$ $$\tag{2}\Gamma(x) \Gamma(x + \frac{1}{2}) \sim \Gamma(2x)$$ $$\tag{3}\Gamma(x) \Gamma(x + \frac{1}{3}) \Gamma(x + \frac{2}{3}) \sim \Gamma(3x)$$ $$\tag{4}\Gamma(x) \Gamma(x + \frac{1}{7}) \cdots \Gamma(x + \frac{6}{7}) \sim \Gamma(7x)$$ The first one is reflection formula, the others are instances of multiplication theorems.

I will omit the $\Gamma$ sign, firstly, use $(2)$ on $11/42$: $$C:=\frac{{\left( {\frac{2}{7}} \right)\left( {\frac{{11}}{{42}}} \right)}}{{\left( {\frac{1}{{21}}} \right)}} \sim \frac{{\left( {\frac{2}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)}} \tag{*}$$ Use $(3)$ on $2/7$ with $x=2/21$: $$C \sim \frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{16}}{{21}}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)}} =\frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)}}$$ Use $(4)$ on $1/21$ with $x=1/21$: $$C\sim \frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{{21}}} \right)}} \sim \frac{{\left( {\frac{2}{{21}}} \right)\left( {\frac{3}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}{{\left( {\frac{1}{3}} \right)}}\left( {\frac{4}{{21}}} \right)\left( {\frac{7}{{21}}} \right)\left( {\frac{{10}}{{21}}} \right)\left( {\frac{{13}}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)\left( {\frac{{19}}{{21}}} \right)$$ Note that $1/3$ in the denominator cancels with $7/21$ in the numerator, some terms cancelled each other via reflection formula, leaving $$C \sim \left( {\frac{3}{7}} \right)\left( {\frac{4}{{21}}} \right)\left( {\frac{{13}}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right) $$ Use $(3)$ on $4/21$ and $13/21$: $$C \sim \left( {\frac{3}{7}} \right)\frac{{\left( {\frac{4}{7}} \right)}}{{\left( {\frac{{11}}{21}} \right)\left( {\frac{6}{7}} \right)}}\frac{{\left( {\frac{{13}}{7}} \right)}}{{\left( {\frac{{20}}{{21}}} \right)\left( {\frac{9}{7}} \right)}}\left( {\frac{{16}}{{21}}} \right) \sim \frac{1}{{\left( {\frac{{11}}{{21}}} \right)}}\frac{1}{{\left( {\frac{{20}}{{21}}} \right)\left( {\frac{2}{7}} \right)}}\left( {\frac{{16}}{{21}}} \right)$$ Finally, use reflection formula to make $20/21$ onto the numerator gives $$C \sim \frac{{\left( {\frac{1}{{21}}} \right)\left( {\frac{{16}}{{21}}} \right)}}{{\left( {\frac{2}{7}} \right)\left( {\frac{{11}}{{21}}} \right)}}$$ Now compare this with $(\ast)$ gives $C \sim \frac{1}{C} $, hence $C$ can be expressed as product of algebraic numbers and a rational power of $\pi$. Note that $C \sim 1/C$ explains why square root appears over sine terms of the result.

What this constant is can be figured out by performing above steps, I hope someone with more computational stamina than me can find it out explicitly.

I am typing some (informal) book on sagemath, with focus on structural application, and this post was an ideal occasion / setting to use sage in a natural, non-trivial way, here i am copy+pasting the full (computer aided, quick) proof, so that in similar situations one has a straight line to the solution.

It is handy, and it makes typing easier to use a better notation for $\Gamma(k/42)$ for all potentially relevant values of $k$, so let us set formally $$ \color{red}{ [k] = \Gamma\left(\frac k{42}\right) }\ ,\qquad k=1,2,\dots, 20,21, 22, \dots, 41,\dots\ \ . $$ Then a duplication formula is $$ [k]\;[k+21]=\text{(Known constant)}\cdot[2k]\ , $$ Note: In the programming section we consider the purely multiplicative functional equations (FEs), which are the Gauss multiplication FEs, and the reflexion FEs, written additively, then use notationally $x_k$ instead of $[k]$ (in the additive world), and the above relation reads $x_k+x_{k+21}-x_{2k}$ is "known", this leads to a system of linear equations, and for our purposes it is enough to pass to the homogeneous version and search for a writing of $x_{11}+x_{12}-x_2$ in terms of the collected equations.

Sage brings us straightforward to the finish, and suggests then (code in the sequel) to look at the relations:

$$ \begin{aligned}{} [4] \cdot[4+6] \cdot[4+12] \cdot[4+18] \cdot[4+24] \cdot[4+30] \cdot[4+36] \cdot[7\cdot 4]^{-1} &=(2\pi)^{6/2}\cdot 7^{1/2-7\cdot 4/42} &&\text{ to power $+1$}\ , \\ % [6] \cdot\color{magenta}{[6+6]} \cdot[6+12] \cdot[6+18] \cdot[6+24] \cdot[6+30] \cdot[6+36] \cdot[7\cdot 6]^{-1} &=(2\pi)^{6/2}\cdot 7^{1/2-7\cdot 6/42} &&\text{ to power $+1$}\ , \\[3mm] % \color{blue}{[2]} \cdot[2+14] \cdot[2+28] \cdot[3\cdot 2]^{-1} &=(2\pi)^{2/2}\cdot 3^{1/2-3\cdot 2/42} &&\text{ to power $-1$}\ , \\ % [4] \cdot[4+14] \cdot[4+28] \cdot\color{magenta}{[3\cdot 4]^{-1}} &=(2\pi)^{2/2}\cdot 3^{1/2-3\cdot 4/42} &&\text{ to power $-1$}\ , \\ % [8] \cdot[8+14] \cdot[8+28] \cdot[3\cdot 8]^{-1} &=(2\pi)^{2/2}\cdot 3^{1/2-3\cdot 8/42} &&\text{ to power $+1$}\ , \\[3mm] % \color{red}{[11]} \cdot[11+21] \cdot[2\cdot 11]^{-1} &=(2\pi)^{1/2}\cdot 2^{1/2-2\cdot 11/42} &&\text{ to power $+2$}\ , \\[3mm] % \color{blue}{[2]} \cdot[42-2] &=\pi\cdot \left(\sin\frac{2\pi}{42}\right)^{-1} &&\text{ to power $-1$}\ , \\ % [6] \cdot[42-6] &=\pi\cdot \left(\sin\frac{6\pi}{42}\right)^{-1} &&\text{ to power $-2$}\ , \\ % [8] \cdot[42-8] &=\pi\cdot \left(\sin\frac{8\pi}{42}\right)^{-1} &&\text{ to power $-1$}\ , \\ % [10] \cdot[42-10] &=\pi\cdot \left(\sin\frac{10\pi}{42}\right)^{-1} &&\text{ to power $-1$}\ . % \end{aligned} $$ We multiply the equations above, taken to the mentioned powers, only the colored factors survive: $$ \begin{aligned} \color{red}{[11]^2} \cdot \color{magenta}{[12]^2} \cdot \color{blue}{[2]^{-2}} &= (2\pi)^6 \cdot \pi^{-5} \cdot 2^{1-22/21} \cdot 3^{-1/2-1/7} \cdot 7^{-2/3} \cdot \\ &\qquad\qquad\cdot \sin^2\frac{6\pi}{42} \cdot \sin\frac{2\pi}{42} \cdot \sin\frac{8\pi}{42} \cdot \sin\frac{10\pi}{42} \end{aligned} $$ which is our relation. One can separate the algebraic number, and rewrite putting in evidence $ \color{red}{\frac{11}{42}} + \color{magenta}{\frac{12}{42}} = \color{blue}{\frac{2}{42}} + \color{green}{\frac{21}{42}} $: $$ \begin{aligned} \frac { \color{red}{\Gamma\left(\frac{11}{42}\right)} \color{magenta}{\Gamma\left(\frac{12}{42}\right)} } { \color{blue}{\Gamma\left(\frac{2}{42}\right)} \color{green}{\Gamma\left(\frac{21}{42}\right)} } &= \frac {\displaystyle 2^3\cdot\sin\frac{\pi}7 \sqrt{ \sin\frac{\pi}{21} \cdot \sin\frac{4\pi}{21} \cdot \sin\frac{5\pi}{21}} } {\displaystyle2^{1/42}\cdot 3^{9/28}\cdot 7^{1/3}} \\ &= \frac {\displaystyle 2^{5/4} (5-\sqrt{21})^{1/4} \sin\frac{\pi}7 } {\displaystyle 2^{1/42}\cdot 3^{9/28}\cdot 7^{1/3}} \ . \end{aligned} $$ That's all.

$\square$

As promised, some computer art work support the above.

• (1)

Numerical check of the equalities above:

LHS = gamma(11/42) * gamma(12/42) / gamma(2/42) / gamma(21/42)
RHS1 = 8 * sin(pi/7) * sqrt(prod([sin(k*pi/21) for k in [1,4,5]])) / 2^(1/42) / 3^(9/28) / 7^(1/3)
RHS2 = 2^(5/4) * sin(pi/7) * (5-sqrt(21))^(1/4) / 2^(1/42) / 3^(9/28) / 7^(1/3)

print "LHS =", LHS.n()
print "RHS1 =", RHS1.n()
print "RHS2 =", RHS2.n()

which gives

LHS = 0.299625085598959
RHS1 = 0.299625085598959
RHS2 = 0.299625085598959

• (2)

Minimal polynomial of the expression (sine product) under the square root:

K.<u> = CyclotomicField(84)        # 84 = 7*4*3
u42, u21, u4 = u^2, u^4, u^21
s1 = (u42^1 - 1/u42^1) / 2 / u4    # sine of 2.1pi/42 =  pi/21
s4 = (u42^4 - 1/u42^4) / 2 / u4    # sine of 2.4pi/42 = 4pi/21
s5 = (u42^5 - 1/u42^5) / 2 / u4    # sine of 2.5pi/42 = 5pi/21
print (8*s1*s4*s5).minpoly()

which gives, leading then immediately to the factor $(5-\sqrt{21})$:

x^4 - 5*x^2 + 1

• (3)

As promised, the code that found the needed "linear" relation to be used:

R = PolynomialRing(QQ, 'x', 42 )     # quick init, we do not use x0
v = R.gens()
for k in range(42):
    exec('x%s = v[%s]' % (k, k) )    # so x1 is indeed x1, x2 is indeed x2...

def normalized_variable(k):
    return v[ k % 42 ]

def eq(times, k):
    """times should divide 42 in the caller, Gauss FE linearized, no constant."""
    inc = ZZ(42/times)
    return ( sum([ normalized_variable(k + j*inc)
                   for j in range(times) ])
             - normalized_variable(times*k) )

equations = (
    [ eq(times, k)
      for times in [7, 3, 2] # ZZ(42).divisors()[ ::-1 ]
      for k in [ 1..ZZ(42/times) ]
      if  times > 1
      # and ( times != 7 or k == 1 )
    ]
    +
    [ v[k] + v[42-k] for k in [1..21]
      if k in [2, 6, 8, 10] ]
    # last is a psychological condition, knowing the result,
    # exactly this condition makes us go straightforward to the result,  
    # else we have a hard work in the cyclotomic field of all sine values,
    # which is harder than parking the gamma values in each other...
)

J = R.ideal(equations)
f = (x11 + x12 - x2)

print "Is f = %s in J? %s" % ( f, f in J )
lif = f.lift(J)

for r in range(len(equations)):
    if lif[r]:
        print '%+4s TIMES %s' % (lif[r], equations[r])

The above gives:

Is f = -x2 + x11 + x12 in J? True

 1/2 TIMES x4 + x10 + x16 + x22 + x34 + x40
 1/2 TIMES x6 + x12 + x18 + x24 + x30 + x36
-1/2 TIMES x2 - x6 + x16 + x30
-1/2 TIMES x4 - x12 + x18 + x32
 1/2 TIMES x8 + x22 - x24 + x36
   1 TIMES x11 - x22 + x32
-1/2 TIMES x2 + x40
  -1 TIMES x6 + x36
-1/2 TIMES x8 + x34
-1/2 TIMES x10 + x32
sage: 

which "is" the solution.