Filtering text through a shell command in Emacs

Solution 1:

You can select a region and type `C-u M-| command RET', and it replaces the region with the command output in the same buffer due to the interactive prefix argument of shell-command-on-region.

Solution 2:

I wrote this a few years back, it might help you:

(defun generalized-shell-command (command arg)
  "Unifies `shell-command' and `shell-command-on-region'. If no region is
selected, run a shell command just like M-x shell-command (M-!).  If
no region is selected and an argument is a passed, run a shell command
and place its output after the mark as in C-u M-x `shell-command' (C-u
M-!).  If a region is selected pass the text of that region to the
shell and replace the text in that region with the output of the shell
command as in C-u M-x `shell-command-on-region' (C-u M-|). If a region
is selected AND an argument is passed (via C-u) send output to another
buffer instead of replacing the text in region."
  (interactive (list (read-from-minibuffer "Shell command: " nil nil nil 'shell-command-history)
                     current-prefix-arg))
  (let ((p (if mark-active (region-beginning) 0))
        (m (if mark-active (region-end) 0)))
    (if (= p m)
        ;; No active region
        (if (eq arg nil)
            (shell-command command)
          (shell-command command t))
      ;; Active region
      (if (eq arg nil)
          (shell-command-on-region p m command t t)
        (shell-command-on-region p m command)))))

I've found this function to be very helpful. If you find it useful as well, I suggest binding it to some function key for convenience, personally I use F3:

(global-set-key [f3] 'generalized-shell-command)

Solution 3:

Late edit: As much as I appreciate the upvotes, Jurta's answer is the way to go. And Greg's hack is neater than mine.

I'll leave the rest of this here because it might be worth something, but...

M-x shell-command-on-region, which appears to be bound to M-| by default.

I see that this does not do exactly what Rohit asked for. Using C-h f shell-command-on-region reveals that the desired behavior is available in the non-interactive version of the command (by setting the argument replace to non-nil). We should be able to write a wrapper to do this.

Try this (load it into *scratch* and run M-x eval-buffer, if it works, copy it to your .emacs file):

(defun shell-command-on-region-replace (start end command)
  "Run shell-command-on-region interactivly replacing the region in place"
  (interactive (let (string) 
         (unless (mark)
           (error "The mark is not set now, so there is no region"))
         ;; Do this before calling region-beginning
         ;; and region-end, in case subprocess output
         ;; relocates them while we are in the minibuffer.
         ;; call-interactively recognizes region-beginning and
         ;; region-end specially, leaving them in the history.
         (setq string (read-from-minibuffer "Shell command on region: "
                            nil nil nil
                            'shell-command-history))
         (list (region-beginning) (region-end)
               string)))
  (shell-command-on-region start end command t t)
  )

And note as I say in the comments that this is not a very emacsy thing to do. But I think it works.

For any readers who don't know how to select a region:

1. Move the "point" (current cursor position) to one end of the region, and use C-space to activate the "mark"
2. Move the point to the other end of the region
3. Your done, invoke the command